[Grzesiek1]

To run Internet Explorer 7, you need Windows XP SP2.

Step 1

Download Internet Explorer 7 Beta 2 (11.9 MB). You shouldn't try this with the latest IE7 Beta 3.

Step 2

Use WinRar (you can download a free trial) to extract the files from the setup to a folder - C:\Program Files\Internet Explorer 7.

If you don't want to use WinRar, open the command prompt, use cd to go to the folder where the exe is located and type "IE7BETA2-WindowsXP-x86-enu.exe /X" (or the appropriate setup name).

Step 3

Create a new file named ie7.bat in that folder, and copy the code below (courtesy of Jon Galloway):

@ECHO OFF
TITLE IE7 Launcher 1.4

ECHO IE7 STANDALONE LAUNCHER 1.4
ECHO Updated for IE7 Beta 2 Preview
ECHO.
ECHO Do not close this window or it will not clean up after itself properly.
ECHO You can pass a URL into this batch file, like this:
ECHO ie7.bat www.microsoft.com
ECHO.
ECHO When you close IE7, this will remove the registry key and shut itself down.
ECHO.
ECHO Setting up IE7 for standalone mode...
PUSHD %~dp0

ECHO Removing IE7 registry key and set the version vector to "7.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}]
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\Interface\{000214E5-0000-0000-C000-000000000046}]
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="7.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg

REN SHLWAPI.DLL SHLWAPI.DLL.BAK
TYPE NUL > IEXPLORE.exe.local
ECHO Running IE7...
iexplore.exe "%1"

:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
:: Delete the temporary REG file
DEL %TEMP%.\IE7Fix.reg

ECHO Removing IE7 standalone files...
REN SHLWAPI.DLL.BAK SHLWAPI.DLL
DEL IEXPLORE.exe.local

:: Set the old version vector "6.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="6.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
REGEDIT /S %TEMP%.\IE7Fix.reg
DEL %TEMP%.\IE7Fix.reg

POPD
ECHO Complete, closing...


Step 4

In the same folder, create a new file ie7.vbs with this code:
Set oShell = CreateObject("WScript.Shell")
oShell.Run "ie7.bat", 0, True


Step 5

Create a shortcut on the desktop to ie7.vbs. Change the icon of the shortcut to one from IE7's iexplore.exe.

Step 6

Go to the subfolder update and run xmllitesetup.exe (this way, IE7 will have tabs).

Now you have a standalone Internet Explorer 7 that runs along with Internet Explorer 6. You can launch IE7 from the shortcut you've created on the desktop.

?ródło: http://googlesystem.blogs...-7-without.html